Cloud Storage 버킷으로 전역 외부 애플리케이션 부하 분산기 설정

콘솔

Google Cloud 계정에 로그인합니다. Google Cloud를 처음 사용하는 경우 계정을 만들고 Google 제품의 실제 성능을 평가해 보세요. 신규 고객에게는 워크로드를 실행, 테스트, 배포하는 데 사용할 수 있는 $300의 무료 크레딧이 제공됩니다.

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Roles required to select or create a project

• Select a project: Selecting a project doesn't require a specific IAM role—you can select any project that you've been granted a role on.
• Create a project: To create a project, you need the Project Creator role (roles/resourcemanager.projectCreator), which contains the resourcemanager.projects.create permission. Learn how to grant roles.

Go to project selector

Verify that billing is enabled for your Google Cloud project.

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Roles required to select or create a project

• Select a project: Selecting a project doesn't require a specific IAM role—you can select any project that you've been granted a role on.
• Create a project: To create a project, you need the Project Creator role (roles/resourcemanager.projectCreator), which contains the resourcemanager.projects.create permission. Learn how to grant roles.

Go to project selector

Verify that billing is enabled for your Google Cloud project.

gcloud

gcloud config set project PROJECT_ID

PROJECT_ID를 이 가이드에 사용 중인 프로젝트로 바꿉니다.

Terraform

export GOOGLE_CLOUD_PROJECT=PROJECT_ID

콘솔

1. Google Cloud 콘솔에서 Cloud Storage 버킷 페이지로 이동합니다.

   Cloud Storage 버킷으로 이동

2. 버킷 만들기를 클릭합니다.

3. 버킷 이름 지정 상자에 이름 지정 가이드라인에 따라 전역적으로 고유한 이름을 입력합니다.

4. 데이터 저장 위치 선택을 클릭합니다.

5. 위치 유형을 리전으로 설정합니다.

6. 위치를 europe-north1로 설정합니다. 이 가이드에서는 BUCKET_1_NAME입니다.

7. 만들기를 클릭합니다.

8. 버킷을 클릭하여 Cloud Storage 버킷 페이지로 돌아갑니다. 다음 안내를 따라 두 번째 버킷을 만들되, 위치를 us-east1로 설정합니다. 이 가이드에서는 BUCKET_2_NAME입니다.

gcloud

gcloud storage buckets create gs://BUCKET_1_NAME --project=PROJECT_ID --default-storage-class=standard --location=europe-north1 --uniform-bucket-level-access

gcloud storage buckets create gs://BUCKET_2_NAME --project=PROJECT_ID --default-storage-class=standard --location=us-east1 --uniform-bucket-level-access

BUCKET_1_NAME 및 BUCKET_2_NAME을 만들려는 버킷의 이름으로 바꿉니다.

Terraform

버킷을 만들려면 google_storage_bucket 리소스를 사용합니다.

# Create Cloud Storage buckets
resource "random_id" "bucket_prefix" {
  byte_length = 8
}

resource "google_storage_bucket" "bucket_1" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-1"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

resource "google_storage_bucket" "bucket_2" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-2"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

Terraform 구성을 적용하거나 삭제하는 방법은 기본 Terraform 명령어를 참조하세요.

gcloud

1. terminal Cloud Shell 활성화를 클릭합니다.

2. Cloud Shell에서 다음 명령어를 실행하여 버킷 이름 변수를 Cloud Storage 버킷 이름으로 바꿉니다.

gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://BUCKET_1_NAME/never-fetch/

gcloud storage cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://BUCKET_2_NAME/love-to-fetch/

Terraform

항목을 버킷에 복사하려면 google_storage_bucket_object 리소스를 사용하면 됩니다.

resource "google_storage_bucket_object" "cat_image" {
  name         = "never-fetch/three-cats.jpg"
  source       = "images/three-cats.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_1.name
}

resource "google_storage_bucket_object" "dog_image" {
  name         = "love-to-fetch/two-dogs.jpg"
  source       = "images/two-dogs.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_2.name
}

또는 null_resource 리소스를 사용합니다.

resource "null_resource" "upload_cat_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://${google_storage_bucket.bucket_1.name}/never-fetch/"
}
}

resource "null_resource" "upload_dog_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://${google_storage_bucket.bucket_2.name}/love-to-fetch/"
}
}

콘솔

모든 사용자에게 버킷의 객체를 볼 수 있는 액세스 권한을 부여하려면 버킷마다 다음 절차를 반복합니다.

1. Google Cloud 콘솔에서 Cloud Storage 버킷 페이지로 이동합니다.

   Cloud Storage 버킷으로 이동

2. 버킷 이름을 클릭한 다음 권한 탭을 클릭합니다.

3. 추가를 클릭합니다.

4. 새 주 구성원 상자에 allUsers를 입력합니다.

5. 역할 선택 상자에서 Cloud Storage > 스토리지 객체 뷰어를 선택합니다.

6. 저장을 클릭합니다.

7. 공개 액세스 허용을 클릭합니다.

gcloud

모든 사용자에게 버킷의 객체를 볼 수 있는 액세스 권한을 부여하려면 다음 명령어를 실행합니다.

gcloud storage buckets add-iam-policy-binding gs://BUCKET_1_NAME --member=allUsers --role=roles/storage.objectViewer

gcloud storage buckets add-iam-policy-binding gs://BUCKET_2_NAME --member=allUsers --role=roles/storage.objectViewer

Terraform

모든 사용자에게 버킷의 객체를 볼 수 있는 액세스 권한을 부여하려면 google_storage_bucket_iam_member 리소스를 사용하고 allUsers 구성원을 지정합니다.

# Make buckets public
resource "google_storage_bucket_iam_member" "bucket_1" {
  bucket = google_storage_bucket.bucket_1.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

resource "google_storage_bucket_iam_member" "bucket_2" {
  bucket = google_storage_bucket.bucket_2.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

콘솔

서비스 계정에만 버킷의 객체를 볼 수 있는 액세스 권한을 부여하려면 버킷마다 다음 절차를 반복합니다.

1. Google Cloud 콘솔에서 버킷 페이지로 이동합니다.

   버킷으로 이동

2. 액세스를 사용 설정할 버킷으로 이동하여 권한 탭을 클릭합니다.

3. 권한 섹션의 주 구성원별로 보기 탭에서 person_add액세스 권한 부여를 클릭합니다.

4. 주 구성원 추가 섹션의 새 주 구성원 필드에 호출 서비스 계정의 이메일 주소(service-PROJECT_NUM@https-lb.iam.gserviceaccount.com)를 입력합니다.

5. 역할 할당 섹션의 역할 선택 필드에서 Cloud Storage > 스토리지 객체 뷰어를 선택합니다. 이 역할은 읽기 전용 액세스 권한을 제공합니다.

6. 저장을 클릭합니다.

또한 버킷에서 제공되는 모든 콘텐츠가 캐시되도록 캐시 모드를 설정하여 모든 콘텐츠 강제 캐시로 지정하고 최대 TTL 값을 지정합니다.

gcloud

서비스 계정에만 버킷의 객체를 볼 수 있는 액세스 권한을 부여하려면 다음 명령어를 실행합니다.

  gcloud storage buckets add-iam-policy-binding gs://BUCKET_1_NAME \
      --member=serviceAccount:service-PROJECT_NUM@https-lb.iam.gserviceaccount.com \
      --role=roles/storage.objectViewer

  gcloud storage buckets add-iam-policy-binding gs://BUCKET_2_NAME \
      --member=serviceAccount:service-PROJECT_NUM@https-lb.iam.gserviceaccount.com \
      --role=roles/storage.objectViewer

다음을 바꿉니다.

• BUCKET_1_NAME 및 BUCKET_2_NAME: 사용할 Cloud Storage 버킷의 이름

• PROJECT_NUM: Google Cloud 프로젝트 수

또한 버킷에서 제공되는 모든 콘텐츠가 캐시되도록 캐시 모드를 설정하여 모든 콘텐츠 강제 캐시로 지정하고 최대 TTL 값을 지정합니다.

콘솔

1. Google Cloud 콘솔에서 외부 IP 주소 페이지로 이동합니다.

   외부 IP 주소로 이동

2. 고정 주소 예약을 클릭합니다.

3. 이름 상자에 example-ip를 입력합니다.

4. 네트워크 서비스 등급을 프리미엄으로 설정합니다.

5. IP 버전을 IPv4로 설정합니다.

6. 유형을 전역으로 설정합니다.

7. 예약을 클릭합니다.

gcloud

gcloud compute addresses create example-ip \
    --network-tier=PREMIUM \
    --ip-version=IPV4 \
    --global

예약된 IPv4 주소를 확인합니다.

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Terraform

외부 IP 주소를 예약하려면 google_compute_global_address 리소스를 사용합니다.

# Reserve IP address
resource "google_compute_global_address" "default" {
  name = "example-ip"
}

콘솔

부하 분산기 유형 선택

1. Google Cloud 콘솔에서 부하 분산 페이지로 이동합니다.

   부하 분산으로 이동

2. 부하 분산기 만들기를 클릭합니다.
3. 부하 분산기 유형에서 애플리케이션 부하 분산기(HTTP/HTTPS)를 선택하고 다음을 클릭합니다.
4. 공개 또는 내부에서 공개(외부)를 선택하고 다음을 클릭합니다.
5. 전역 또는 단일 리전 배포에서 전역 워크로드에 적합을 선택하고 다음을 클릭합니다.
6. 부하 분산기 생성에서 전역 외부 애플리케이션 부하 분산기를 선택하고 다음을 클릭합니다.
7. 구성을 클릭합니다.

기본 구성

1. 이름 상자에 http-lb를 입력합니다.

백엔드 구성

1. 백엔드 구성을 클릭합니다.

2. 백엔드 서비스 및 백엔드 버킷 상자를 클릭하고 백엔드 버킷 만들기를 클릭합니다.

3. 백엔드 버킷 이름 상자에 cats를 입력합니다.

4. Cloud Storage 버킷 상자에서 찾아보기를 클릭합니다.

5. BUCKET_1_NAME을 선택하고 선택을 클릭합니다. 먼저 cats 백엔드 버킷을 만들면 기본적으로 일치하지 않는 모든 트래픽 요청이 전달됩니다. 부하 분산기에서 기본 백엔드 버킷의 리디렉션 규칙을 변경할 수 없습니다.

6. 만들기를 클릭합니다.

7. 같은 프로세스로 dogs라는 백엔드 버킷을 만들고 BUCKET_2_NAME을 선택합니다.

8. 확인을 클릭합니다.

라우팅 규칙 구성

라우팅 규칙은 트래픽의 전달 방식을 결정합니다. 라우팅을 구성하려면 외부 애플리케이션 부하 분산기의 URL 맵의 구성 구성요소에 해당하는 호스트 규칙 및 경로 일치자를 설정합니다. 이 예시에 대한 규칙을 설정하려면 다음 안내를 따르세요.

1. 라우팅 규칙을 클릭합니다.
2. dogs의 경우 호스트 필드에 *를, 경로 필드에 /love-to-fetch/*를 입력합니다.

프런트엔드 구성

1. 프런트엔드 구성을 클릭합니다.

2. 다음 옵션이 이러한 값으로 구성되었는지 확인합니다.

   속성	값(값 입력 또는 지정된 옵션 선택)
   프로토콜	HTTP
   네트워크 서비스 등급	프리미엄
   IP 버전	IPv4
   IP 주소	example-ip
   포트	80
   선택사항: HTTP 연결 유지 제한 시간	5~1,200초 사이의 제한 시간 값을 입력합니다. 기본값은 610초입니다.

   HTTP 부하 분산기 대신 HTTPS 부하 분산기를 만들려면 SSL 인증서가 있어야 합니다. 다음과 같이 필드를 작성해야 합니다.

   속성	값(값 입력 또는 지정된 옵션 선택)
   프로토콜	HTTP(S)
   네트워크 서비스 등급	Premium
   IP 버전	IPv4
   IP 주소	example-ip
   포트	443
   선택사항: HTTP 연결 유지 제한 시간	5~1,200초 사이의 제한 시간 값을 입력합니다. 기본값은 610초입니다.
   인증서	인증서 저장소 선택에서 인증서 맵 사용 또는 기존 인증서 사용을 선택합니다. 선택에 따라 인증서 맵 또는 기존 인증서를 선택합니다.
   (선택사항) HTTP-HTTPS 리디렉션 사용 설정	이 체크박스를 사용하여 리디렉션을 사용 설정합니다. 이 체크박스를 사용 설정하면 HTTPS 부하 분산기와 동일한 IP 주소를 사용하는 추가적인 부분 HTTP 부하 분산기를 만들고 HTTP 요청을 부하 분산기의 HTTPS 프런트엔드로 리디렉션합니다. 이 체크박스는 HTTPS 프로토콜이 선택되었고 예약된 IP 주소가 사용될 때만 선택할 수 있습니다.

3. 완료를 클릭합니다.

구성 검토

1. 검토 및 완료를 클릭합니다.

2. 프런트엔드, 호스트 및 경로 규칙, 백엔드 버킷을 검토합니다.

3. 만들기를 클릭하고 부하 분산기가 생성될 때까지 기다립니다.

4. 부하 분산기의 이름을 클릭합니다(http-lb).

5. 다음 작업을 위해 부하 분산기의 IP 주소를 기록합니다. 이 가이드에서는 IP_ADDRESS라고 합니다.

gcloud

백엔드 구성

gcloud compute backend-buckets create cats \
  --gcs-bucket-name=BUCKET_1_NAME

gcloud compute backend-buckets create dogs \
  --gcs-bucket-name=BUCKET_2_NAME

URL 맵 구성

gcloud compute url-maps create http-lb \
  --default-backend-bucket=cats

gcloud compute url-maps add-path-matcher http-lb \
  --path-matcher-name=path-matcher-2 \
  --new-hosts=* \
  --backend-bucket-path-rules="/love-to-fetch/*=dogs" \
  --default-backend-bucket=cats

대상 프록시 구성

HTTP 부하 분산기의 경우 대상 HTTP 프록시를 만들어 요청을 URL 맵으로 라우팅합니다.

gcloud compute target-http-proxies create http-lb-proxy \
  --http-keep-alive-timeout-sec=HTTP_KEEP_ALIVE_TIMEOUT_SEC \
  --url-map=http-lb

HTTP_KEEP_ALIVE_TIMEOUT_SEC를 5~1,200초의 클라이언트 HTTP 연결 유지 제한 시간 값으로 바꿉니다. 기본값은 610초입니다. 이 필드는 선택사항입니다.

HTTPS 부하 분산기의 경우 대상 HTTPS 프록시를 만들어 요청을 URL 맵으로 라우팅합니다. 대상 프록시는 HTTPS 부하 분산기의 SSL 인증서 리소스를 보유하므로 이 단계에서 인증서 또는 인증서 맵을 연결합니다.

gcloud compute target-https-proxies create https-lb-proxy \
  --http-keep-alive-timeout-sec=HTTP_KEEP_ALIVE_TIMEOUT_SEC \
  --url-map=http-lb \
  --ssl-certificates=SSL_CERTIFICATE_NAME

다음을 바꿉니다.

• HTTP_KEEP_ALIVE_TIMEOUT_SEC: 5~1,200초의 클라이언트 HTTP 연결 유지 제한 시간 값 기본값은 610초입니다. 이 필드는 선택사항입니다.
• SSL_CERTIFICATE_NAME: Compute Engine SSL 인증서의 이름입니다. 대신 인증서 관리자 인증서 맵을 만든 경우 --ssl-certificates=SSL_CERTIFICATE_NAME을 --certificate-map=CERTIFICATE_MAP_NAME으로 바꿉니다.

전달 규칙 구성

HTTP 부하 분산기의 경우 포트 80의 수신 HTTP 요청을 대상 HTTP 프록시로 라우팅하는 전역 전달 규칙을 만듭니다.

gcloud compute forwarding-rules create http-lb-forwarding-rule \
  --load-balancing-scheme=EXTERNAL_MANAGED \
  --network-tier=PREMIUM \
  --address=example-ip \
  --global \
  --target-http-proxy=http-lb-proxy \
  --ports=80

HTTPS 부하 분산기의 경우 포트 443의 수신 HTTPS 요청을 대상 HTTPS 프록시로 라우팅하는 전역 전달 규칙을 만듭니다.

gcloud compute forwarding-rules create https-lb-forwarding-rule \
  --load-balancing-scheme=EXTERNAL_MANAGED \
  --network-tier=PREMIUM \
  --address=example-ip \
  --global \
  --target-https-proxy=https-lb-proxy \
  --ports=443

Terraform

부하 분산기를 만들려면 다음 Terraform 리소스를 사용합니다.

백엔드 구성

백엔드 서비스를 만들려면 google_compute_backend_bucket 리소스를 사용합니다.

# Create LB backend buckets
resource "google_compute_backend_bucket" "bucket_1" {
  name        = "cats"
  description = "Contains cat image"
  bucket_name = google_storage_bucket.bucket_1.name
}

resource "google_compute_backend_bucket" "bucket_2" {
  name        = "dogs"
  description = "Contains dog image"
  bucket_name = google_storage_bucket.bucket_2.name
}

URL 맵 구성

URL 맵을 만들려면 google_compute_url_map 리소스를 사용합니다.

# Create url map
resource "google_compute_url_map" "default" {
  name = "http-lb"

  default_service = google_compute_backend_bucket.bucket_1.id

  host_rule {
    hosts        = ["*"]
    path_matcher = "path-matcher-2"
  }
  path_matcher {
    name            = "path-matcher-2"
    default_service = google_compute_backend_bucket.bucket_1.id

    path_rule {
      paths   = ["/love-to-fetch/*"]
      service = google_compute_backend_bucket.bucket_2.id
    }
  }
}

대상 프록시 구성

대상 HTTP 프록시를 만들려면 google_compute_target_http_proxy 리소스를 사용합니다.

# Create HTTP target proxy
resource "google_compute_target_http_proxy" "default" {
  name    = "http-lb-proxy"
  url_map = google_compute_url_map.default.id
}

전달 규칙 구성

전달 규칙을 만들려면 google_compute_global_forwarding_rule 리소스를 사용합니다.

# Create forwarding rule
resource "google_compute_global_forwarding_rule" "default" {
  name                  = "http-lb-forwarding-rule"
  ip_protocol           = "TCP"
  load_balancing_scheme = "EXTERNAL_MANAGED"
  port_range            = "80"
  target                = google_compute_target_http_proxy.default.id
  ip_address            = google_compute_global_address.default.id
}

참고: 모드를 기본 애플리케이션 부하 분산기로 변경하려면 load_balancing_scheme 속성을 "EXTERNAL_MANAGED" 대신 "EXTERNAL"로 설정합니다.

Terraform 구성을 적용하거나 삭제하는 방법은 기본 Terraform 명령어를 참조하세요.

콘솔

Google Cloud 콘솔은 지원되지 않습니다.

gcloud

curl 명령어를 사용하여 다음 URL의 응답을 테스트합니다. HTTP 부하 분산기의 경우 IP_ADDRESS를 부하 분산기의 IPv4 주소로 바꿉니다. HTTPS 부하 분산기의 경우 http://IP_ADDRESS를 https://DOMAIN로 바꿉니다. 여기서 DOMAIN는 부하 분산기의 IP 주소로 확인되는 SSL 인증서와 연결된 도메인 이름입니다.

curl http://IP_ADDRESS/love-to-fetch/two-dogs.jpg

curl http://IP_ADDRESS/never-fetch/three-cats.jpg

콘솔

1. Google Cloud 콘솔에서 부하 분산 페이지로 이동합니다.

   부하 분산으로 이동

2. 수정할 부하 분산기의 이름을 클릭합니다.
3. edit수정을 클릭합니다.
4. 프런트엔드 구성을 클릭합니다.
5. 고급 기능을 펼칩니다. HTTP 연결 유지 제한 시간에 제한 시간 값을 입력합니다.
6. 업데이트를 클릭합니다.
7. 변경사항을 검토하려면 검토 및 완료를 클릭한 다음 업데이트를 클릭합니다.

gcloud

HTTP 부하 분산기의 경우 gcloud compute target-http-proxies update 명령어를 사용하여 대상 HTTP 프록시를 업데이트합니다.

      gcloud compute target-http-proxies update TARGET_HTTP_PROXY_NAME \
          --http-keep-alive-timeout-sec=HTTP_KEEP_ALIVE_TIMEOUT_SEC \
          --global
    

HTTPS 부하 분산기의 경우 gcloud compute target-https-proxies update 명령어를 사용하여 대상 HTTPS 프록시를 업데이트합니다.

      gcloud compute target-https-proxies update TARGET_HTTPS_PROXY_NAME \
          --http-keep-alive-timeout-sec=HTTP_KEEP_ALIVE_TIMEOUT_SEC \
          --global
    

다음을 바꿉니다.

• TARGET_HTTP_PROXY_NAME: 대상 HTTP 프록시의 이름입니다.
• TARGET_HTTPS_PROXY_NAME: 대상 HTTPS 프록시의 이름입니다.
• HTTP_KEEP_ALIVE_TIMEOUT_SEC: HTTP 연결 유지 제한 시간 값(5~600초 사이)